webcache/settings.gradle at main · magictractor/webcache · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
// An explicit rootProject.name is best practice.
// See https://docs.gradle.org/current/userguide/best_practices_general.html#name_your_root_project.
rootProject.name = "magictractor-webcache"

rootProject.buildFileName = "${rootProject.name}.gradle".replace("magictractor-", "")

// includeBuild(../{project}) entries may be added to
// settings.local.gradle to link to source in sibling projects
// instead of a jar file.
def localSettings = file('settings.local.gradle')
if (localSettings.exists()) {
    apply from: localSettings
}

// settings.gradle may be copied without modification across magictractor.co.uk projects,
// so the version catalog may include libraries that are not used in this project.
//
// https://docs.gradle.org/current/userguide/version_catalogs.html
dependencyResolutionManagement {
    versionCatalogs {
        libs {
            version('slf4j', '2.0.17')
            // Logback 1.3 will run on JDK 8. Logback 1.4 and later need JDK 11+.
            version('logback', '1.3.15')
            version('guava', '33.4.8-jre')
            version('junit', '5.13.3')
            version('junit-platform', '1.13.3')
            version('assertj', '3.27.3')

            // Logging.
            library('slf4j.api', 'org.slf4j', 'slf4j-api').versionRef('slf4j')
            library('jcl.over.slf4j', 'org.slf4j', 'jcl-over-slf4j').versionRef('slf4j')
            library('logback.classic', 'ch.qos.logback', 'logback-classic').versionRef('logback')

            // Utils.
            library('guava', 'com.google.guava', 'guava').versionRef('guava')

            // Testing.
            library('junit.jupiter', 'org.junit.jupiter', 'junit-jupiter').versionRef('junit')
            library('junit.jupiter.platform', 'org.junit.platform', 'junit-platform-launcher').versionRef('junit-platform')
            library('assertj', 'org.assertj', 'assertj-core').versionRef('assertj')


//            library('commons-lang3', 'org.apache.commons', 'commons-lang3').version {
//                strictly '[3.8, 4.0['
//                prefer '3.9'
//            }
        }
    }
}