chitin/justfile at main · chitin-dev/chitin · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
# Chitin developer and CI command shortcuts.
#
# Keep recipes as thin wrappers around Cargo and documentation commands. CI should use
# the same recipes as local development so that the two paths cannot drift.

default:
  @just --list

fmt:
  cargo fmt --all

fmt-check:
  cargo fmt --all --check

check:
  cargo check --workspace --locked

clippy:
  cargo clippy --workspace --all-targets --locked -- -D warnings

test:
  cargo test --workspace --locked

databases-test:
  cargo test -p chitin-databases --features test-support --locked

# The Rust workflow intentionally mirrors .github/workflows/check.yml.
ci: fmt-check check clippy test databases-test

verify: fmt-check check clippy test databases-test

bio-test:
  cargo test -p chitin-bio --locked

bio-online:
  cargo test -p chitin-bio --test rcsb_online downloads_configured_structures_and_parses_them -- --ignored --nocapture

# Parse flat PDB/mmCIF fixtures without network access.
bio-local path="crates/chitin-bio/tests/fixtures/rcsb":
  CHITIN_BIO_FIXTURE_ROOT="{{path}}" cargo test -p chitin-bio --test rcsb_local -- --nocapture

# Requires the ignored local PDBx dictionary beside the generated schema.
generate-mmcif-schema:
  cargo run -p chitin-mmcif-schema --locked
  rustfmt --edition 2024 crates/chitin-bio/src/structure/mmcif/schema.rs

desktop path=".":
  cargo run -p chitin-desktop -- "{{path}}"

# Launch the native PTY and VT-emulation integration example.
terminal-debug path=".":
  cargo run -p chitin-desktop --example terminal-debug -- "{{path}}"

# Rebuild the browser WASM package before starting Vite's development server.
browser-dev:
  pnpm --dir browser wasm:build
  pnpm --dir browser dev

wgpu-example path="." *args:
  cargo run --example chitin-wgpu-desktop -- "{{path}}" {{args}}

msms-debug path="structure.cif" *args:
  cargo run --release --example msms-debug -- "{{path}}" {{args}}

showcase:
  cargo run -p chitin-ui --example primitive-showcase

cli *args:
  cargo run -p chitin -- {{args}}

docs-build:
  shiroa build --mode dyn-paged --path-to-root /chitin/ docs

docs-serve:
  shiroa serve --mode dyn-paged docs

build-desktop-release:
  cargo build -p chitin-desktop --release --locked

build-cli-release:
  cargo build -p chitin --release --locked

build-release: build-desktop-release build-cli-release