Android-TiffBitmapFactory/build.gradle at master · Beyka/Android-TiffBitmapFactory · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
// Top-level and library build file.
buildscript {
    repositories {
        google()
        mavenCentral()
        gradlePluginPortal()
    }
    dependencies {
        classpath "com.android.tools.build:gradle:8.7.3"
    }

    ext["ossrhUsername"] = ''
    ext["ossrhPassword"] = ''
}

plugins {
    id "com.android.library"
    id "maven-publish"
    id "signing"
    id "com.gradleup.nmcp" version "0.0.9"
}

group = 'com.github.beyka'
version = '0.9.9.3'

android {
    namespace 'org.beyka.tiffbitmapfactory'
    compileSdk 36

    def softwareName

    defaultConfig {
        minSdk 21
        targetSdk 34
        versionCode 988
        versionName "0.9.9.3"

        softwareName = "\"" + project.name + "-" + versionName + "\""
    }

    buildFeatures {
        buildConfig true
    }

    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
            buildConfigField("String", "softwarename", softwareName)
        }
        debug {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
            buildConfigField("String", "softwarename", softwareName)
        }
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }

    ndkVersion "28.2.13676358"

    sourceSets.main {
        jni.srcDirs = []
        jniLibs.srcDir 'src/main/libs'
    }

    lint {
        abortOnError false
    }

    publishing {
        singleVariant("release") {
            withSourcesJar()
            withJavadocJar()
        }
    }
}

dependencies {
}

publishing {
    publications {
        release(MavenPublication) {
            groupId = 'com.github.beyka'
            artifactId = 'Android-TiffBitmapFactory'
            version = '0.9.9.3'
            pom {
                name = 'Android-TiffBitmapFactory'
                description = 'Библиотека декодирования TIFF файлов для Android'
                url = 'https://github.com'
                licenses {
                    license {
                        name = 'The Apache Software License, Version 2.0'
                        url = 'http://apache.org'
                    }
                }
                developers {
                    developer {
                        id = 'Beyka'
                        name = 'Aleksey Bey'
                        email = 'leshabey@gmail.com'
                    }
                }
                scm {
                    connection = 'scm:git:://github.com'
                    developerConnection = 'scm:git:ssh://://github.com'
                    url = 'https://github.com'
                }
            }
        }
    }
}
def secretProps = new Properties()
def secretPropsFile = rootProject.file("local.properties")
if (!secretPropsFile.exists()) {
    secretPropsFile = file("local.properties")
}
if (secretPropsFile.exists()) {
    secretPropsFile.withInputStream { secretProps.load(it) }
}

signing {
    useInMemoryPgpKeys(
            secretProps.getProperty("signing.keyId"),
            secretProps.getProperty("signing.key"),
            secretProps.getProperty("signing.password")
    )
}

afterEvaluate {
    publishing.publications.release.from(components.release)
    signing.sign publishing.publications.release
}

nmcp {
    publish("release") {
        username = secretProps.getProperty("ossrhUsername")
        password = secretProps.getProperty("ossrhPassword")
        publicationType = "USER_MANAGED"
    }
}